Create an enumerated type attribute with default value

Hi,

I want to create a enumerated type attribute with default value.
In the DXL Reference Manual, there is the function

AttrDef create(object
property value...
(default defVal)
attribute(string attrName))

Even if the default defVal is in the "create" function, my attribute does not have the default value.
 

string errMsg = null
string td = "AT SUIVI"
string defaut = "en rédaction"
string names[] = {"en rédaction", "A vérifier", "A modifier", "Pris en compte", "Validé"}
int values[] = {3,4,0,1,2}
int colors[] = {21, 39, 13, 31, 25}    
AttrType at = create (td, names, values, colors, errMsg)      // create my enumerated type
AttrDef ad = create (default "en rédaction") object type at attribute ad      // create my enumerated type attribute

I suppose my default value is not well defined...

Re: Create an enumerated type attribute with default value
SystemAdmin - Fri Sep 28 10:22:09 EDT 2012

• Pekka Mäkinen - http://www.softqa.eu/

Re: Create an enumerated type attribute with default value
Estebell - Mon Oct 01 02:52:28 EDT 2012

I tried to create my attribute like that :
 

AttrDef ad = create (default "value 1") object type at attribute ad

But I still have an error on this line.

Re: Create an enumerated type attribute with default value
Mathias Mamsch - Mon Oct 01 06:42:56 EDT 2012

AttrDef ad = create (default "value 1") object type at attribute ad

The "type" and "attribute" functions take a string argument. From you code piece it looks like you are trying to pass AttrDef and AttrType? Try
 

AttrDef ad = create (default "value 1") object type "Text" attribute "MyAttributeName"

Regards, Mathias

Mathias Mamsch, IT-QBase GmbH, Consultant for Requirement Engineering and D00RS

Re: Create an enumerated type attribute with default value
Estebell - Mon Oct 01 08:37:58 EDT 2012

AttrDef ad = create (default "value 1") object type "Text" attribute "MyAttributeName"

I use at and ad which are arguments of my function create.
Here is my full code...
 

//create attribute definition
void createAttr(string ad, string at) {
AttrDef ad2 = create (default "value 1") object type at attribute ad
}
 
//create attribute type 
void createTypeSu(string td) {
    string errMsg = null
        string defaut = "en rédaction"
        string names[] = {"en rédaction", "A vérifier", "A modifier", "Pris en compte", "Validé"}
        int values[] = {3,4,0,1,2}
        int colors[] = {21, 39, 13, 31, 25} 
    AttrType at = create (td, names, values, colors, errMsg)            // on crée le type AT Suivi
} 
 
 
//main
Module m = current
attType = find(m, "AT Suivi")
if (null (attType)){
        createTypeSu("AT Suivi")
}
 
AttrDef attDef = find(m, "AS Exigence")
if (null (attDef)){
createAttr ("AS Exigence", "AT Exigence")
}
 
attDef = find(m, "AS Suivi")
if (null (attDef)){
createAttr ("AS Suivi", "AT Suivi")
}

Re: Create an enumerated type attribute with default value
llandale - Mon Oct 01 13:43:59 EDT 2012

//create attribute definition
void createAttr(string ad, string at) {
AttrDef ad2 = create (default "value 1") object type at attribute ad
}
 
//create attribute type 
void createTypeSu(string td) {
    string errMsg = null
        string defaut = "en rédaction"
        string names[] = {"en rédaction", "A vérifier", "A modifier", "Pris en compte", "Validé"}
        int values[] = {3,4,0,1,2}
        int colors[] = {21, 39, 13, 31, 25} 
    AttrType at = create (td, names, values, colors, errMsg)            // on crée le type AT Suivi
} 
 
 
//main
Module m = current
attType = find(m, "AT Suivi")
if (null (attType)){
        createTypeSu("AT Suivi")
}
 
AttrDef attDef = find(m, "AS Exigence")
if (null (attDef)){
createAttr ("AS Exigence", "AT Exigence")
}
 
attDef = find(m, "AS Suivi")
if (null (attDef)){
createAttr ("AS Suivi", "AT Suivi")
}

1. The [module|object] phrase must be first.
2. The "attribute name" phrase has to be last.
3. The "(default val)" phrase has to be second to last

• create(object type at (default "value 1") attribute ad)

Re: Create an enumerated type attribute with default value
llandale - Mon Oct 01 13:48:12 EDT 2012

Folks need to read the DXL manual quite a bit more precisely then is intuitively apparent.
As Written:

create(attribute definition) 
Syntax 
AttrDef create([module|object]
               [property value]...
              [(default defVal)]
                 attribute(string attrName))

As Commented:

create(attribute definition) 
Syntax 
AttrDef create(
               [module|object]            // Clearly this phrase is first
               [property value]...        // various properties, any order, including "type"
              [(default defVal)]          // specify Default value after the properties
                 attribute(string attrName)) // specify attribute name last

-Louie

Re: Create an enumerated type attribute with default value
Mathias Mamsch - Mon Oct 01 15:24:06 EDT 2012

create(attribute definition) 
Syntax 
AttrDef create([module|object]
               [property value]...
              [(default defVal)]
                 attribute(string attrName))

create(attribute definition) 
Syntax 
AttrDef create(
               [module|object]            // Clearly this phrase is first
               [property value]...        // various properties, any order, including "type"
              [(default defVal)]          // specify Default value after the properties
                 attribute(string attrName)) // specify attribute name last

Order is completely unimportant for the execution, only for the syntax (And the DXL manual is not a holy book). From the perm definitions all the modifiers (inherit, date, dxl, locale, description, hidden, history, type, multi, values, default, changeBars) can either go to the left or to the right side of the attribute tag which must be present. An exception are object and module which can only be on the left side of attribute, if specified. However since the DOORS parser is sometimes stupid, it does not understand all variants. Here for example you need some extra () for the parser to eat the statement
 

print null create (object  (attribute "XYYY")  (inherit true)   (type "Text")) (changeBars true) // works
print null create object  (attribute "XYYY")  (inherit true)   (type "Text") (changeBars true) // fails

Anyway back to the original post, my guess is you are falling for different errors. In your first post you reused 'at':

...
AttrType at = create (td, names, values, colors, errMsg)      // HERE AT is an AttrType! 
AttrDef ad = create (default "en rédaction") object type at attribute ad   // Here DXL expects a string!
...

In your second post which should be your FULL code, you are missing the creation of the 'AT Exigence' type, which makes that code fail. Then when you tried changing the default value you missed, that your your enumeration type "... (default 'value 1') ..." is not a valid default value.

So the following code works perfectly for me:

//create attribute definition
void createAttr(string ad, string at) {
   AttrDef ad2 = create (default "en rédaction") object type at attribute ad
}
 
//create attribute type 
void createTypeSu(string td) {
   string errMsg = null
   string defaut = "en rédaction"
   string names[] = {"en rédaction", "A vérifier", "A modifier", "Pris en compte", "Validé"}
   int values[] = {3,4,0,1,2}
   int colors[] = {21, 39, 13, 31, 25}    
   AttrType at = create (td, names, values, colors, errMsg)             // on crée le type AT Suivi
} 
 
 
//main
Module m = current
AttrType attType = find(m, "AT Suivi")
if (null (attType)){
   createTypeSu("AT Suivi")
}
 
AttrDef attDef = find(m, "AS Suivi")
if (null (attDef)){
   createAttr ("AS Suivi", "AT Suivi")
}

Maybe that helps, regards, Mathias

Mathias Mamsch, IT-QBase GmbH, Consultant for Requirement Engineering and D00RS

Re: Create an enumerated type attribute with default value
llandale - Tue Oct 02 17:18:58 EDT 2012

print null create (object  (attribute "XYYY")  (inherit true)   (type "Text")) (changeBars true) // works
print null create object  (attribute "XYYY")  (inherit true)   (type "Text") (changeBars true) // fails

...
AttrType at = create (td, names, values, colors, errMsg)      // HERE AT is an AttrType! 
AttrDef ad = create (default "en rédaction") object type at attribute ad   // Here DXL expects a string!
...

//create attribute definition
void createAttr(string ad, string at) {
   AttrDef ad2 = create (default "en rédaction") object type at attribute ad
}
 
//create attribute type 
void createTypeSu(string td) {
   string errMsg = null
   string defaut = "en rédaction"
   string names[] = {"en rédaction", "A vérifier", "A modifier", "Pris en compte", "Validé"}
   int values[] = {3,4,0,1,2}
   int colors[] = {21, 39, 13, 31, 25}    
   AttrType at = create (td, names, values, colors, errMsg)             // on crée le type AT Suivi
} 
 
 
//main
Module m = current
AttrType attType = find(m, "AT Suivi")
if (null (attType)){
   createTypeSu("AT Suivi")
}
 
AttrDef attDef = find(m, "AS Suivi")
if (null (attDef)){
   createAttr ("AS Suivi", "AT Suivi")
}

• print null create object (attribute "XYYY") (inherit true) (type "Text") (changeBars true)
• print name module target lnk

• print (null create (object (attribute "XYYY") (inherit true) (type "Text") (changeBars true)))
• print name (module (target (lnk)))

• AttrDef ad = create (object (attribute "XYYY") (inherit true) (type "Text") (changeBars true))

Re: Create an enumerated type attribute with default value
Mathias Mamsch - Tue Oct 02 18:46:41 EDT 2012

Just to be clear - null, inherit, object, type, changeBars are also functions that take one parameter so you would need to write:
 

print (null (create (object ((attribute ("XYYY")) (inherit (true)) (type ("Text")) (changeBars (true))))))

And this by the way

print null create object ( (attribute "XYYY") (inherit true) (type "Text") (changeBars true))

should do exactly what it is supposed to do. 'object' is a function that takes an 'Attr__' parameter, so it will be interpreted like this even if you remove the parenthesis. There is no danger that the DXL parser would confuse it with the object(int) function.

Regards, Mathias

Mathias Mamsch, IT-QBase GmbH, Consultant for Requirement Engineering and D00RS

Re: Create an enumerated type attribute with default value
llandale - Wed Oct 03 17:07:49 EDT 2012

print (null (create (object ((attribute ("XYYY")) (inherit (true)) (type ("Text")) (changeBars (true))))))

print null create object ( (attribute "XYYY") (inherit true) (type "Text") (changeBars true))

Didn't realize it but I guess I had perceived a difference between actual user "functions" and system things that are actually functions. "changeBars" is yes technically a function but it is not used that way; it's used as some kind of descripter.

In this case, "create" is the primary function and it is clear is deserves parenthesis, expecially since it appears to have multiple parameters even though it only has a single one. I see in the doors.exe the "object" reference is also a function, in this case composed of a series of things that can be concatenated to form an "AttrDef__" variable.

For whatever it is worth, my "fCreateAttr()" function does this:

ad    = create(module object                                    //-
         type NameType  history DoHistory       changeBars DoBars       //-
         date DoDate    inherit DoInherit       attribute NameAttr
             )

I think that is fairly readable even if I violate my own parenthesis rules.

-Louie

The following fails with concatenation errors:

• print null create object ( (attribute "XYYY") (inherit true) (type "Text") (changeBars true))

I'm a little confused with precedence, but I'm guessing the right-most (changeBars true) phrase of type "AttrBarsVal__" cannot concatenate with the next (type "text") phrase of type AttrType__. You need a full right-most phrase of type "AttrDef__" for that to work; putting (attribute "XYYY") at the right acomplishes that; and you end up with the Syntax sequence in the DXL manual.
Anyway, I strongly prefer readability over ... well most everything else.

Re: Create an enumerated type attribute with default value
Mathias Mamsch - Thu Oct 04 04:00:19 EDT 2012

ad    = create(module object                                    //-
         type NameType  history DoHistory       changeBars DoBars       //-
         date DoDate    inherit DoInherit       attribute NameAttr
             )

Yeah it is confusing. Technically The following perms are defined to concatenate those "predicates" to either the left OR the right side of the attribute function.
 

Left Side                               Right Side
AttrDef__ ::.. (AttrDef__, AttrBarsVal__)       AttrDef__ ::.. (AttrBarsVal__, AttrDef__)
AttrDef__ ::.. (AttrDef__, AttrDateVal__)       AttrDef__ ::.. (AttrDateVal__, AttrDef__)
AttrDef__ ::.. (AttrDef__, AttrDefVal__)        AttrDef__ ::.. (AttrDefVal__, AttrDef__)
AttrDef__ ::.. (AttrDef__, AttrDescVal__)       AttrDef__ ::.. (AttrDescVal__, AttrDef__)
AttrDef__ ::.. (AttrDef__, AttrDxlVal__)        AttrDef__ ::.. (AttrDxlVal__, AttrDef__)
AttrDef__ ::.. (AttrDef__, AttrHideVal__)       AttrDef__ ::.. (AttrHideVal__, AttrDef__)
AttrDef__ ::.. (AttrDef__, AttrHistVal__)       AttrDef__ ::.. (AttrHistVal__, AttrDef__)
AttrDef__ ::.. (AttrDef__, AttrInhVal__)        AttrDef__ ::.. (AttrInhVal__, AttrDef__)
AttrDef__ ::.. (AttrDef__, AttrLocaleVal__)     AttrDef__ ::.. (AttrLocaleVal__, AttrDef__)
AttrDef__ ::.. (AttrDef__, AttrMultiVal__)      AttrDef__ ::.. (AttrMultiVal__, AttrDef__)
AttrDef__ ::.. (AttrDef__, AttrType__)          AttrDef__ ::.. (AttrType__, AttrDef__)

The attribute function itself is the only function that will return an AttrDef__ in the first place, without needing one itself, so it must be present. So the code should work, since attribute "..." creates an AttrDef__ and then the predicates should be concatenated to the right side. Unfortunately the DXL parser does not handle the last predicate well. this works:

print null create object ((attribute "XYYY") (inherit true) (type "Text")) (changeBars true)

So inherit and type can be concatenated to the right side of attribute, but the last predicate can't. I would consider that a bug of the parser. Anyway you are right, the most readable form is to have create with () and put the predicates inside. The good thing to know here however is that you can do something like this:

AttrDef createAttr (string sName, string sType, bool bModule, bool bObject /* , ... other predicates ... */) {
    AttrDef__ def = (type sType) /* ... other predicates  ... */ attribute sName
    if (bModule) def = module def
    if (bObject) def = object def 
    // ...
    AttrDef result = create (def) 
    return result
}

This way you can have a 'real function' for creating your attributes.

Regards, Mathias

Mathias Mamsch, IT-QBase GmbH, Consultant for Requirement Engineering and D00RS